#!/usr/local/bin/perl -w
# $Id: fotokey,v 1.16 2003/09/27 07:57:06 pme Exp pme $
# fotokey software makes it easy to publish web photo galleries.
# cf http://fotokey.org
#
# Copyright 2003 by Paul English <paul@fotokey.org>
#
# This file is part of fotokey.
#
# fotokey is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# fotokey is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with fotokey; if not, write to the Free Software Foundation,
# Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

use strict;
use File::Copy;

my $furl = "http://fotokey.org";
my $fdir = "/usr/local/fotokey";

# See sub main() below.

my $debug = 0;
sub doit($) {
  my $command = shift;
  if ($debug) {
    print "doit $command\n";
  }
  return system($command);
}
	 
# -----------------------------------------------------------------
# the "o_" functions output different parts of the generated files.

sub o_navigation($$$$) { # output the text navigation at top left of vga
  my ($n,$fileno,$w,$h) = @_;

  print "\n<!-- begin:navigation -->\n" .
    "<tr>\n<td><div class=nav>\n" .
    "<a href=\"../\">&laquo; top</a> | \n";

  if ($n>1) {
    o_goto (fotofile ($n-1,"html"),"&laquo; prev</a> | \n");
  } else {
    print "<font color=\"gray\">&laquo; prev</font> | \n";
  }

  if ($n<$fileno) {
    o_goto (fotofile($n+1,"html"),"next&nbsp;&raquo;</a>");
  } else {
    print "<font color=\"gray\">next&nbsp;&raquo;</font>";
  }

  print "</div></td>\n\n" .
    "<td align=\"right\">\n";
  o_buttons($n,$w,$h);
  print "</td></tr>\n" .
    "<!-- end:navigation -->\n\n";
}

sub o_goto($$) { # output html/js to go to url w/o messing browser history
  my ($url,$text) = @_;
  print "<a href='javascript:location.replace(\"" . $url . "\");'>" . $text;
}

sub o_keymap($$) { # output keymap nav for this vga; see next/prev below
  my ($n,$fileno) = @_;
  print "<script>\n" .
    "document.onkeyup = fotokeyKey;\n" .
    "function fotokeyNav(key) {\n";
  if ($n>1) {		# ok to allow left-arrow to go to previous vga
    print "  if (key==37) location.replace(\""
      . fotofile($n-1,"html") . "\");\n";
  }
  if ($n<$fileno) {	# ok to allow right arrow to go to next vga
    print "  if (key==39) location.replace(\""
      . fotofile($n+1,"html") . "\");\n";
  }
  print "}\n</script>\n";
}

sub o_buttonSetup() {		# preloads the top right button images
  print "<script>buttonSetup();</script>\n";
}

sub o_buttons($$$) {		# output the buttons on top right of vga
  my ($n,$w,$h) = @_;
  my $url = current_url();
  my $ns = sprintf("%03d",$n);	# 001 etc
  my $f = fotofile($n);		# 001.jpg etc

  print <<EOF;
<form name="sflyc4p" method="POST"
  style="margin-bottom:0;"
  action="http://www.shutterfly.com/c4p/UpdateCart.jsp">

<a href="../lib/email.cgi?url=$url&n=$ns"><img
  src="../lib/email.gif" name="bemail"
  onmouseover="return buttonSet(this,true);" onmouseout="return buttonSet(this,false);"
  width="18" height="18" border="0" alt="Email this photo."></a>
<img src="../lib/camera.gif" name="bcamera"
  onmouseover="return buttonSet(this,true);" onmouseout="return buttonSet(this,false);"
  width="18" height="18" border="0" alt="View camera settings for this photo."
  onclick='fotokeyToggle("exif","info");'>
<input name="submit" type="image"
  onmouseover="return buttonSet(this,true);" onmouseout="return buttonSet(this,false);"
  src="../lib/printer.gif" name="bprinter"
  border="0" alt="Send this photo to shutterfly for ordering prints.">
<img src="../lib/info.gif" name="binfo"
  onmouseover="return buttonSet(this,true);" onmouseout="return buttonSet(this,false);"
  width="18" height="18" border="0" alt="Info about fotokey galleries."
  onclick='fotokeyToggle("info","exif");'>
<input type="hidden" name="addim" value="1">
<input type="hidden" name="protocol" value="SFP,100">
<input type="hidden" name="pid" value="C4PP">
<input type="hidden" name="psid" value="TEST">
<input type="hidden" name="referid" value="f7">
<input type="hidden" name="returl" value="$url">
<input type="hidden" name="imnum" value=2>
<input type="hidden" name="imsel" value=1>
<input type="hidden" name="imraw-1" value="$url/huge/$f">
<input type="hidden" name="imrawheight-1" value="$h">
<input type="hidden" name="imrawwidth-1" value="$w">
<input type="hidden" name="imthumb-1" value="$url/thumbs/$f">
<input type="hidden" name="imbkprntb-1" value="$f">
</form>
EOF
}

# -----------------------------------------------------------------
# tiny utility functions:

sub fotofile {			# filename such as 001.jpg or 002.html
  my $suffix = (@_ == 2) ? $_[1] : "jpg";
  return sprintf("%03d.%s",$_[0],$suffix); # bug: use File::Spec
}

sub o_updated($) {		# output the updated time stamp at end of html
  my ($file_handle) = @_;
  print $file_handle
    "<p class=small>Updated " .  localtime() .
    "\n by <a href=\"$furl\">fotokey</a>\n";
}

sub o_start($) {		# output the start of the html file
  my ($file_handle) = @_;
  my $gen = "<!-- MACHINE GENERATED by " . $0 . " " . localtime() . " -->";
  print $file_handle <<EOF;
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN">
$gen
<html>
<head>
<title></title>
<link rel="stylesheet" href="../lib/fotokey.css" type="text/css">
EOF
}

sub current_url() {		# i'm sure there's an easier way to do this
  my $dir = $ENV{'PWD'};
  if ($dir =~ m'^/v/') {	# /v/domain.com/www/foo.html
    $dir =~ s (/www/) (/) ;
    $dir =~ s (^/v/) (http://www.);
  } else {			# /u/paul/domain.com/www/foo.html
    $dir =~ s (/www/) (/) ;
    $dir =~ s (/u/\w+/) (http://www.) ;
  }
  return $dir;
}

sub get_dimensions($) {
  my $info = `pnmfile $_[0]`;
  my @words = split(" ",$info);
  if (@words == 8) {
    return ($words[3], $words[5]);
  } else {
    return (0, 0);
  }
}

# -----------------------------------------------------------------
sub setup_lib() {
  opendir (DH, "$fdir/lib")
    or die "Cannot open $fdir/lib: $!";
  my ($fname, $file);
  foreach $fname (readdir DH) {
    my $file = "$fdir/lib/$fname";
    if (! -d $file) {
      copy ($file,"lib/$fname")
        or die "Cannot copy $file to lib directory: $!";
      if (-x $file) { # for email.cgi etc
	chmod (0555, "lib/$fname")
	  or die "Cannot chmod +x lib/$fname: $!";
      }
    }
  }
  closedir DH;
}

# -----------------------------------------------------------------
# main()

sub main() {
  ( -d $fdir )
    or die ("\$fdir $fdir does not exist\nstopped");

  my $url = current_url();

  opendir DIR, '.'
    or die "Could not read `.': $!";

  my @photos;
  while (defined (my $f = readdir DIR)) {
    $f =~ /^\./ and next;	# Skip dot files.
    $f =~ /\.jpe?g$/i or next;	# Allow .jpg, .JPG, .jpeg, etc.
    push @photos, $f;
  }
  closedir DIR;

  @photos
    or die ("no jpg files in `.', stopped");
  my ($file, $dir);
  foreach $dir (qw/lib thumbs vga huge/) {
    unless ( -d $dir ) {
      mkdir ($dir, 0755)
	or die ("Can't mkdir $dir: $!");
    }
  }
  setup_lib();

  # rename files so we can have prev/next buttons in the vga html files
  my $fileno = 0;
  foreach $file (sort @photos) {
    my $huge = "huge/" . fotofile(++$fileno);
    rename ($file, $huge)
      or die ("Can't move $file to $huge: $!");
  }
  print "Processing $fileno photos for $url...\n";

  my $n;				# photo index
  if ( -f "index.html" ) {
    rename ("index.html", "index.save.html")
      or die ("Can't rename index.html: $!");
  }
  open (INDEX, ">index.html")
    or die ("Can't create a new index.html: $!");
  o_start(*INDEX);
  print (INDEX "</head>\n<body bgcolor=\"#e6e6e6\">\n");

  if (-e "header.html") {
    print (INDEX "<!--#include virtual=\"header.html\"-->\n");
  }

  # -----------------------------------------------------------------
  foreach $n (1 .. $fileno) {	# process each photo
    $file = fotofile($n);		# 001.jpg etc
    my $ns = sprintf("%03d",$n);	# just the 001 part
    print $file;			# status to command line

    # create the thumbnail and vga sized photo
    !doit ("djpeg -pnm huge/$file > tmp")
      or die ("djpeg huge/$file, stopped");
    my ($w,$h) = get_dimensions("tmp");
    print " $w x $h $ns "; ###
    my $vga_html = "vga/$ns.html";
    print INDEX "<a href=\"$vga_html\"><img src=\"thumbs/$file\"\n" .
      " border=\"0\" alt=\"Click for larger size\"></a>\n";
    # " onmouseover=\"this.border=1;\" onmouseout=\"this.border=0;\"\n" .
    print ": ";

    unless (-e "thumbs/$file") {
      !doit ("pnmscale -xysize 300 300 < tmp | ppmtojpeg > thumbs/$file")
	or die ("pnmscale|ppmtojpeg for thumbs/$file failed, stopped");
      print "thumbs ";
    }
    unless (-e "vga/$file") {
      !doit ("pnmscale -xysize 800 600 < tmp | ppmtojpeg > vga/$file")
	or die ("pnmscale|ppmtojpeg for vga/$file failed, stopped");
      print "vga ";
    }
    unlink "tmp";

    # create the vga wrapper html
    open (VGA, ">$vga_html")
      or die ("can't open >$vga_html: $!");
    select (VGA);
    o_start(*VGA);
    print "<script src=\"../lib/fotokey.js\"></script>\n";
    o_keymap($n,$fileno);
    o_buttonSetup();
    print "</head>\n<body bgcolor=\"#e6e6e6\">\n";
    print "<table border=\"0\">\n" .
      "<tr><td colspan=\"2\">\n<b>title</b>\n" .
      "<span class=count>($n of $fileno)</span></td></tr>\n";
    o_navigation($n,$fileno,$w,$h);
    print "<tr><td colspan=\"2\"><div id=\"vga\" class=\"frame\">\n" .
      "<a href=\"../huge/$file\"><img\n" .
      " src=\"$file\" border=\"0\"></a></div></td></tr>\n";

    print "<tr><td valign=\"top\">\n" .
      "<div id=\"thumb\" style=\"display: none\">\n" .
      "<img src=\"../thumbs/" . fotofile($n) . "\" border=\"0\"\n" .
      " onclick='fotokeyReset();'></td>\n" .
      "</div></td>\n\n";

    print<<EOF;
<td>
<div id="info" style="display: none">
<p>Use your <b>left</b> and <b>right</b> arrow keys
to navigate to the <b>previous</b> and <b>next</b> photo,
or the <b>up</b> arrow to return to the <b>index</b>.

<p>Click one of the icons on the top right:
<ul>
<li><img src="../lib/email.gif"
  width="18" height="18" border="0" alt="email">
send the current photo by email to one of your friends.

<li><img src="../lib/camera.gif"
  width="18" height="18" border="0" alt="camera">
show camera settings such as shutter speed and aperture.

<li><img src="../lib/printer.gif"
 width="18" height="18" border="0" alt="printer">
upload the large version of this photo to Shutterfly,
to order prints to be sent in the mail. Click <b>Back</b>
after clicking this, to select more photos.
</ul>

<p>There are three sizes of each photo. Click on
the thumbnail or VGA size to open the next larger
size.

<p>Rate a photo by clicking on the appropriate star,
or by pressing a number 1 through 5 on your keyboard.
</div>
EOF

    my @exif = `jhead huge/$file`;
    print "<div id=\"exif\" style=\"display: none\">\n";
    if (@exif>0) {
      print "<pre>\n";
      my $line;
      foreach $line (@exif) {
	print "$line";
      }
      print "</pre><!--exif info extracted via jhead-->\n";
    } else {
      print "No exif information available for this photo.\n";
    }
    print "</div></td></tr></table>\n";

    print<<EOF;
<iframe name="iframe" id="iframe"
 style="width:0px; height:0px; border: 0px" src="blank.html"></iframe>
<p>Rating:<script>starBarDraw();</script>
EOF

    o_updated(*VGA);
    if ($n<$fileno) {		# start download of next image...
      my $next = fotofile($n+1);
      print "<img src=\"$next\" width=\"0\" height=\"0\" alt=\"[cache]\">\n";
    }
    print VGA "</body></html>\n";
    close (VGA)
      or die ("$vga_html: write failed: $!");
    select (STDOUT);
    print "\n";
  }				# foreach photo

  if (-e "footer.html") {
    print (INDEX "<!--#include virtual=\"footer.html\"-->\n");
  }
  o_updated(*INDEX);
  print INDEX "<img src=\"vga/001.jpg\" width=\"0\" height=\"0\" alt=\"[cache]\">\n";
  print INDEX "\n</body></html>\n";
  close (INDEX)
    or die ("index.html: write failed: $!");
  print "Completed " . current_url() . "\n";
  return 0;
}

exit(&main());

# -----------------------------------------------------------------
### Local Variables: ***
### compile-command:"cd /v/fotokey.org/www/sample2;fotokey.reset;fotokey" ***
### End: ***